Портирование из Oracle PL/SQL

В этом разделе объясняются различия между языком PL/pgSQL QHB и языком PL/SQL Oracle, чтобы помочь разработчикам, которые переносят приложения из Oracle® в QHB.

PL/pgSQL во многом похож на PL/SQL. Это блочно-структурированный императивный язык, где все переменные должны быть объявлены. Присвоения, циклы и условия схожи. Основные различия, которые следует учитывать при переносе с PL/SQL на PL/pgSQL, следующие:

  • Если имя, фигурирующее в команде SQL, может быть как именем столбца таблицы, используемой в этой команде, так и ссылкой на переменную функции, PL/SQL обрабатывает его как имя столбца. По умолчанию PL/pgSQL выдаст ошибку, предъявляя претензию о неоднозначности имени. Чтобы изменить это поведение на принятое в PL/SQL, можно указать plpgsql.variable_conflict = use_column, как описано в подразделе Подстановка переменных. Как правило, лучше вообще избегать подобных неоднозначностей, но если вам нужно портировать большой объем кода, зависящего от этого поведения, установка variable_conflict может быть лучшим решением.

  • В QHB тело функции должно быть записано как строковый литерал. Поэтому следует использовать долларовые кавычки или экранировать апострофы в теле функции. (См. подраздел Обработка кавычек.)

  • Имена типов данных часто нуждаются в преобразовании. Например, в Oracle строковые значения обычно объявляются как имеющие тип varchar2, не являющийся стандартным типом SQL. В QHB вместо него следует использовать тип varchar или text. Аналогичным образом нужно будет заменить тип number на numeric или использовать другой числовой тип, если есть более подходящий.

  • Для организации функций в группы используйте схемы вместо пакетов.

  • Поскольку пакетов нет, переменных уровня пакета тоже нет. Это несколько раздражает. Вместо этого можно хранить состояние сеанса во временных таблицах.

  • Целочисленные циклы FOR с REVERSE работают по-разному: PL/SQL ведет обратный отсчет от второго числа к первому, тогда как PL/pgSQL ведет обратный отсчет от первого числа ко второму, поэтому при переносе границы цикла нужно поменять местами. Это неприятная несовместимость, но вряд ли что-то изменится. (См. подраздел FOR (целочисленный вариант).)

  • Циклы FOR по запросам (кроме курсоров) тоже работают по-разному: целевые переменные должны быть объявлены, тогда как PL/SQL всегда объявляет их неявно. Преимущество этого состоит в том, что значения переменных доступны и после выхода из цикла.

  • Существуют различные нотационные различия при использовании переменных курсора.

Примеры портирования

В Примере 9 показано, как портировать простую функцию из PL/SQL в PL/pgSQL.

Пример 9. Портирование простой функции из PL/SQL в PL/pgSQL

Функция Oracle PL/SQL:

CREATE OR REPLACE FUNCTION cs_fmt_browser_version(v_name varchar2,
                                                  v_version varchar2)
RETURN varchar2 IS
BEGIN
    IF v_version IS NULL THEN
        RETURN v_name;
    END IF;
    RETURN v_name || '/' || v_version;
END;
/
show errors;

Давайте рассмотрим эту функцию и разберем различия по сравнению с PL/pgSQL:

  • Имя типа varchar2 нужно заменить на varchar или text. В примерах в этом подразделе мы будем использовать varchar, но зачастую text является лучшим выбором, если вам не нужны определенные ограничения длины строк.

  • Ключевое слово RETURN в прототипе функции (но не в ее теле) в QHB становится RETURNS. Кроме того, IS становится AS, и нужно добавить предложение LANGUAGE, поскольку PL/pgSQL не является единственным возможным языком функций.

  • В QHB тело функции считается строковым литералом, поэтому его нужно заключать в кавычки или знаки доллара. Это заменяет завершающий / в подходе Oracle.

  • В QHB не существует команды show errors, но она и не нужна, поскольку ошибки выводятся автоматически.

Вот как будет выглядеть эта функция при портировании в QHB:

CREATE OR REPLACE FUNCTION cs_fmt_browser_version(v_name varchar,
                                                  v_version varchar)
RETURNS varchar AS $$
BEGIN
    IF v_version IS NULL THEN
        RETURN v_name;
    END IF;
    RETURN v_name || '/' || v_version;
END;
$$ LANGUAGE plpgsql;

В Примере 10 показано, как портировать функцию, создающую другую функцию, и как справиться с возникающими проблемами с кавычками.

Пример 10. Портирование функции, создающей другую функцию, из PL/SQL в PL/pgSQL

Следующая процедура извлекает строки из SELECT и строит большую функцию, результаты которой ради эффективности возвращаются в операторах IF.

Это версия Oracle:

CREATE OR REPLACE PROCEDURE cs_update_referrer_type_proc IS
    CURSOR referrer_keys IS
        SELECT * FROM cs_referrer_keys
        ORDER BY try_order;
    func_cmd VARCHAR(4000);
BEGIN
    func_cmd := 'CREATE OR REPLACE FUNCTION cs_find_referrer_type(v_host IN VARCHAR2,
                 v_domain IN VARCHAR2, v_url IN VARCHAR2) RETURN VARCHAR2 IS BEGIN';

    FOR referrer_key IN referrer_keys LOOP
        func_cmd := func_cmd ||
          ' IF v_' || referrer_key.kind
          || ' LIKE ''' || referrer_key.key_string
          || ''' THEN RETURN ''' || referrer_key.referrer_type
          || '''; END IF;';
    END LOOP;

    func_cmd := func_cmd || ' RETURN NULL; END;';

    EXECUTE IMMEDIATE func_cmd;
END;
/
show errors;

А вот как эта функция может выглядеть в QHB:

CREATE OR REPLACE PROCEDURE cs_update_referrer_type_proc() AS $func$
DECLARE
    referrer_keys CURSOR IS
        SELECT * FROM cs_referrer_keys
        ORDER BY try_order;
    func_body text;
    func_cmd text;
BEGIN
    func_body := 'BEGIN';

    FOR referrer_key IN referrer_keys LOOP
        func_body := func_body ||
          ' IF v_' || referrer_key.kind
          || ' LIKE ' || quote_literal(referrer_key.key_string)
          || ' THEN RETURN ' || quote_literal(referrer_key.referrer_type)
          || '; END IF;' ;
    END LOOP;

    func_body := func_body || ' RETURN NULL; END;';

    func_cmd :=
      'CREATE OR REPLACE FUNCTION cs_find_referrer_type(v_host varchar,
                                                        v_domain varchar,
                                                        v_url varchar)
        RETURNS varchar AS '
      || quote_literal(func_body)
      || ' LANGUAGE plpgsql;' ;

    EXECUTE func_cmd;
END;
$func$ LANGUAGE plpgsql;

Обратите внимание, что тело функции конструируется отдельно и передается через quote_literal для удвоения всех кавычек. Этот метод необходим, потому что мы не можем безопасно использовать долларовые кавычки для определения новой функции: мы не знаем наверняка, какие строки будут интерполированы из поля referrer_key.key_string. (Здесь предполагается, что referrer_key.kind точно всегда имеет значение host, domain или url, но referrer_key.key_string может быть чем угодно, в частности, содержать знаки доллара). На самом деле эта функция улучшена по сравнению с оригиналом на Oracle, потому что она не будет генерировать неработающий код, если в полях referrer_key.key_string или referrer_key.referrer_type содержатся кавычки.

В Примере 11 показано, как портировать функцию с выходными параметрами (OUT), которая манипулирует строками. В QHB нет встроенной функции instr, но ее можно создать, используя комбинацию других функций. В подразделе Приложение описана реализация instr в PL/pgSQL, которой можно воспользоваться для упрощения портирования.

Пример 11. Портирование процедуры с манипулированием строками и параметрами OUT из PL/SQL в PL/pgSQL

Следующая процедура Oracle PL/SQL используется для синтаксического анализа URL-адреса и возврата нескольких элементов (хост, путь и запрос).

Это версия Oracle:

CREATE OR REPLACE PROCEDURE cs_parse_url(
    v_url IN VARCHAR2,
    v_host OUT VARCHAR2,  -- Это будет возвращено
    v_path OUT VARCHAR2,  -- И это тоже
    v_query OUT VARCHAR2) -- И это
IS
    a_pos1 INTEGER;
    a_pos2 INTEGER;
BEGIN
    v_host := NULL;
    v_path := NULL;
    v_query := NULL;
    a_pos1 := instr(v_url, '//');

    IF a_pos1 = 0 THEN
        RETURN;
    END IF;
    a_pos2 := instr(v_url, '/', a_pos1 + 2);
    IF a_pos2 = 0 THEN
        v_host := substr(v_url, a_pos1 + 2);
        v_path := '/';
        RETURN;
    END IF;

    v_host := substr(v_url, a_pos1 + 2, a_pos2 - a_pos1 - 2);
    a_pos1 := instr(v_url, '?', a_pos2 + 1);

    IF a_pos1 = 0 THEN
        v_path := substr(v_url, a_pos2);
        RETURN;
    END IF;

    v_path := substr(v_url, a_pos2, a_pos1 - a_pos2);
    v_query := substr(v_url, a_pos1 + 1);
END;
/
show errors;

Вот возможная конвертация в PL/pgSQL:

CREATE OR REPLACE FUNCTION cs_parse_url(
    v_url IN VARCHAR,
    v_host OUT VARCHAR,  -- Это будет возвращено
    v_path OUT VARCHAR,  -- И это тоже
    v_query OUT VARCHAR) -- И это
AS $$
DECLARE
    a_pos1 INTEGER;
    a_pos2 INTEGER;
BEGIN
    v_host := NULL;
    v_path := NULL;
    v_query := NULL;
    a_pos1 := instr(v_url, '//');

    IF a_pos1 = 0 THEN
        RETURN;
    END IF;
    a_pos2 := instr(v_url, '/', a_pos1 + 2);
    IF a_pos2 = 0 THEN
        v_host := substr(v_url, a_pos1 + 2);
        v_path := '/';
        RETURN;
    END IF;

    v_host := substr(v_url, a_pos1 + 2, a_pos2 - a_pos1 - 2);
    a_pos1 := instr(v_url, '?', a_pos2 + 1);

    IF a_pos1 = 0 THEN
        v_path := substr(v_url, a_pos2);
        RETURN;
    END IF;

    v_path := substr(v_url, a_pos2, a_pos1 - a_pos2);
    v_query := substr(v_url, a_pos1 + 1);
END;
$$ LANGUAGE plpgsql;

Эту функцию можно использовать так:

SELECT * FROM cs_parse_url('http://foobar.com/query.cgi?baz');

В Примере 12 показано, как портировать процедуру, использующую многочисленные функциональные возможности, характерные для Oracle.

Пример 12. Портирование процедуры из PL/SQL в PL/pgSQL

Версия Oracle:

CREATE OR REPLACE PROCEDURE cs_create_job(v_job_id IN INTEGER) IS
    a_running_job_count INTEGER;
BEGIN
    LOCK TABLE cs_jobs IN EXCLUSIVE MODE;

    SELECT count(*) INTO a_running_job_count FROM cs_jobs WHERE end_stamp IS NULL;

    IF a_running_job_count > 0 THEN
        COMMIT; -- освободить блокировку
        raise_application_error(-20000,
                 'Unable to create a new job: a job is currently running.');
    END IF;

    DELETE FROM cs_active_job;
    INSERT INTO cs_active_job(job_id) VALUES (v_job_id);

    BEGIN
        INSERT INTO cs_jobs (job_id, start_stamp) VALUES (v_job_id, now());
    EXCEPTION
        WHEN dup_val_on_index THEN NULL; -- ничего не делать, если оно уже существует
    END;
    COMMIT;
END;
/
show errors

Вот как можно портировать эту процедуру в PL/pgSQL:

CREATE OR REPLACE PROCEDURE cs_create_job(v_job_id integer) AS $$
DECLARE
    a_running_job_count integer;
BEGIN
    LOCK TABLE cs_jobs IN EXCLUSIVE MODE;

    SELECT count(*) INTO a_running_job_count FROM cs_jobs WHERE end_stamp IS NULL;

    IF a_running_job_count > 0 THEN
        COMMIT; -- освободить блокировку
        RAISE EXCEPTION 'Unable to create a new job: a job is currently running'; -- (1)
    END IF;

    DELETE FROM cs_active_job;
    INSERT INTO cs_active_job(job_id) VALUES (v_job_id);

    BEGIN
        INSERT INTO cs_jobs (job_id, start_stamp) VALUES (v_job_id, now());
    EXCEPTION
        WHEN unique_violation THEN -- (2)
            -- ничего не делать, если оно уже существует
    END;
    COMMIT;
END;
$$ LANGUAGE plpgsql;

(1): Синтаксис RAISE значительно отличается от оператора Oracle, хотя основной вариант RAISE имя_исключения работает схожим образом.

(2): Имена исключений, поддерживаемые PL/pgSQL, отличаются от имен Oracle. Набор встроенных имен исключений намного больше (см. главу Коды ошибок QHB). В настоящее время нет способа объявить пользовательские имена исключений, хотя вместо них можно вызывать ошибку с выбранными пользователем значениями SQLSTATE.

На что еще обратить внимание

В этом разделе описываются еще несколько вещей, на которые нужно обратить внимание при портировании функций Oracle PL/SQL в QHB.

Неявный откат после исключений

В PL/pgSQL при захвате исключения предложением EXCEPTION все изменения в базе данных, начиная с блока BEGIN, автоматически откатываются. То есть поведение равнозначно тому, что вы получите в Oracle при:

BEGIN
    SAVEPOINT s1;
    ... некий код ...
EXCEPTION
    WHEN ... THEN
        ROLLBACK TO s1;
        ... некий код ...
    WHEN ... THEN
        ROLLBACK TO s1;
        ... некий код ...
END;

Если вы конвертируете процедуру Oracle, использующую SAVEPOINT и ROLLBACK TO в этом стиле, задача проста: просто опустите эти операторы. Если же у вас есть процедура, использующая SAVEPOINT и ROLLBACK TO по-другому, потребуется хорошенько поразмыслить.

EXECUTE

Версия EXECUTE для PL/pgSQL работает аналогично версии PL/SQL, но не забывайте использовать quote_literal и quote_ident, как описано в подразделе Выполнение динамических команд. Без этих функций конструкции типа EXECUTE 'SELECT * FROM $1'; не будут надежно работать.

Оптимизация функций PL/pgSQL

QHB предоставляет два модификатора при создании функции для оптимизации выполнения: «изменчивость» (всегда ли функция возвращает один и тот же результат, если задавать ей одни и те же аргументы) и «строгость» (возвращает ли функция NULL, если какой-либо аргумент равен NULL). Подробную информацию см. на справочной странице команды CREATE FUNCTION.

При использовании этих атрибутов оптимизации оператор CREATE FUNCTION может выглядеть примерно так:

CREATE FUNCTION foo(...) RETURNS integer AS $$
...
$$ LANGUAGE plpgsql STRICT IMMUTABLE;

Приложение

В этом подразделе содержится код для установки Oracle-совместимых функций instr которые можно использовать для упрощения процесса портирования.

--
-- функции instr, имитирующие аналоги в Oracle
-- Синтаксис: instr(string1, string2 [, n [, m]])
-- где [] означают необязательные параметры.
--
-- Искать в string1, начиная с n-го символа, m-е вхождение
-- string2.  Если n — отрицательное число, искать в обратном направлении, начиная с
-- abs(n)-го символа от конца string1.
-- Если n не передано, предполагать 1 (поиск начинается с первого символа).
-- Если m не передано, предполагать 1 (найти первое вхождение).
-- Возвращает начальный индекс string2 в string1 или 0, если string2 не найдена.
--

CREATE FUNCTION instr(varchar, varchar) RETURNS integer AS $$
BEGIN
    RETURN instr($1, $2, 1);
END;
$$ LANGUAGE plpgsql STRICT IMMUTABLE;


CREATE FUNCTION instr(string varchar, string_to_search_for varchar,
                      beg_index integer)
RETURNS integer AS $$
DECLARE
    pos integer NOT NULL DEFAULT 0;
    temp_str varchar;
    beg integer;
    length integer;
    ss_length integer;
BEGIN
    IF beg_index > 0 THEN
        temp_str := substring(string FROM beg_index);
        pos := position(string_to_search_for IN temp_str);

        IF pos = 0 THEN
            RETURN 0;
        ELSE
            RETURN pos + beg_index - 1;
        END IF;
    ELSIF beg_index < 0 THEN
        ss_length := char_length(string_to_search_for);
        length := char_length(string);
        beg := length + 1 + beg_index;

        WHILE beg > 0 LOOP
            temp_str := substring(string FROM beg FOR ss_length);
            IF string_to_search_for = temp_str THEN
                RETURN beg;
            END IF;

            beg := beg - 1;
        END LOOP;

        RETURN 0;
    ELSE
        RETURN 0;
    END IF;
END;
$$ LANGUAGE plpgsql STRICT IMMUTABLE;


CREATE FUNCTION instr(string varchar, string_to_search_for varchar,
                      beg_index integer, occur_index integer)
RETURNS integer AS $$
DECLARE
    pos integer NOT NULL DEFAULT 0;
    occur_number integer NOT NULL DEFAULT 0;
    temp_str varchar;
    beg integer;
    i integer;
    length integer;
    ss_length integer;
BEGIN
    IF occur_index <= 0 THEN
        RAISE 'argument ''%'' is out of range', occur_index
          USING ERRCODE = '22003';
    END IF;

    IF beg_index > 0 THEN
        beg := beg_index - 1;
        FOR i IN 1..occur_index LOOP
            temp_str := substring(string FROM beg + 1);
            pos := position(string_to_search_for IN temp_str);
            IF pos = 0 THEN
                RETURN 0;
            END IF;
            beg := beg + pos;
        END LOOP;

        RETURN beg;
    ELSIF beg_index < 0 THEN
        ss_length := char_length(string_to_search_for);
        length := char_length(string);
        beg := length + 1 + beg_index;

        WHILE beg > 0 LOOP
            temp_str := substring(string FROM beg FOR ss_length);
            IF string_to_search_for = temp_str THEN
                occur_number := occur_number + 1;
                IF occur_number = occur_index THEN
                    RETURN beg;
                END IF;
            END IF;

            beg := beg - 1;
        END LOOP;

        RETURN 0;
    ELSE
        RETURN 0;
    END IF;
END;
$$ LANGUAGE plpgsql STRICT IMMUTABLE;

Copyright © KVANTOM LLC, 2019-2025